Use Configy to read configuration, let env override config

dub.sdl

@@ -7,7 +7,7 @@ authors "Sönke Ludwig" "Martin Nowak" "Anton Fediushin aka ohdatboi" \
 license "BSL-1.0"
 
 dependency "vibe-d" version="~>0.9.5"
-dependency "dub" version="~>1.29.0"
+dependency "dub" version="~>1.33.0"
 dependency "userman" version="~>0.4.0"
 dependency "uritemplate" version="~>1.0.0"
 subConfiguration "dub" "library-nonet"

dub.selections.json

@@ -5,7 +5,7 @@
 		"botan": "1.12.19",
 		"botan-math": "1.0.3",
 		"diet-ng": "1.8.1",
-		"dub": "1.29.2",
+		"dub": "1.33.0",
 		"eventcore": "0.9.25",
 		"libasync": "0.8.6",
 		"libev": "5.0.0+4.04",

source/app.d

@@ -13,6 +13,7 @@ import dubregistry.repositories.gitlab;
 import dubregistry.registry;
 import dubregistry.web;
 import dubregistry.api;
+import dubregistry.config;
 
 import std.algorithm : sort;
 import std.process : environment;
@@ -86,78 +87,6 @@ void defaultInit(UserManController userMan, DubRegistry registry)
 	}
 }
 
-struct AppConfig
-{
-	string ghauth,
-		   glurl, glauth,
-		   bbuser, bbpassword;
-
-	bool enforceCertificateTrust = false;
-
-	string serviceName = "DUB - The D package registry";
-	string serviceURL = "https://code.dlang.org/";
-	string serviceEmail = "noreply@rejectedsoftware.com";
-
-	string mailServer;
-	ushort mailServerPort;
-	SMTPConnectionType mailConnectionType;
-	string mailClientName;
-	string mailUser;
-	string mailPassword;
-
-	string[] administrators;
-
-
-	void init()
-	{
-		import dub.internal.utils : jsonFromFile;
-		import std.algorithm : map;
-		import std.array : array;
-		auto regsettingsjson = jsonFromFile(NativePath("settings.json"), true);
-		// TODO: use UDAs instead
-		static immutable variables = [
-			["ghauth", "github-auth"],
-			["glurl", "gitlab-url"],
-			["glauth", "gitlab-auth"],
-			["bbuser", "bitbucket-user"],
-			["bbpassword", "bitbucket-password"],
-			["enforceCertificateTrust", "enforce-certificate-trust"],
-			["serviceName", "service-name"],
-			["serviceURL", "service-url"],
-			["serviceEmail", "service-email"],
-			["mailServer", "mail-server"],
-			["mailServerPort", "mail-server-port"],
-			["mailConnectionType", "mail-connection-type"],
-			["mailClientName", "mail-client-name"],
-			["mailUser", "mail-user"],
-			["mailPassword", "mail-password"],
-			["administrators", "administrators"],
-		];
-		static foreach (var; variables) {{
-			alias T = typeof(__traits(getMember, this, var[0]));
-
-			T val = __traits(getMember, this, var[0]);
-
-			if (var[1] in regsettingsjson) {
-				static if (is(T == bool)) val = regsettingsjson[var[1]].get!bool;
-				else static if (isIntegral!T && !is(T == enum)) val = regsettingsjson[var[1]].get!int.to!T;
-				else static if (is(T == string[])) val = regsettingsjson[var[1]].get!(Json[]).map!(j => j.get!string).array;
-				else val = regsettingsjson[var[1]].get!string.to!T;
-			} else {
-				// fallback to environment variables
-				auto ev = environment.get(var[1].replace("-", "_").toUpper);
-				if (ev.length) {
-					static if (is(T == string[]))
-						val = ev.split(',');
-					else val = ev.to!T;
-				}
-			}
-
-			__traits(getMember, this, var[0]) = val;
-		}}
-	}
-}
-
 void main()
 {
 	bool noMonitoring, noServe;
@@ -188,8 +117,7 @@ void main()
 	if (s_mirror.length)
 		validateMirrorURL(s_mirror);
 
-	AppConfig appConfig;
-	appConfig.init();
+	auto appConfig = AppConfig.read();
 
 	version (linux) {
 		if (appConfig.enforceCertificateTrust) {

source/dubregistry/config.d

@@ -0,0 +1,119 @@
+/*******************************************************************************
+
+    Configuration file for dub-registry.
+
+*******************************************************************************/
+
+module dubregistry.config;
+
+import dub.internal.configy.Attributes;
+import dub.internal.configy.Read;
+
+import vibe.mail.smtp;
+
+import std.array;
+import std.conv;
+import std.process;
+import std.string;
+
+public struct AppConfig
+{
+	@Name("github-auth") @Optional
+	string ghauth;
+	@Name("gitlab-url") @Optional
+	string glurl;
+	@Name("gitlab-auth") @Optional
+	string glauth;
+	@Name("bitbucket-user") @Optional
+	string bbuser;
+	@Name("bitbucket-password") @Optional
+	string bbpassword;
+	@Name("enforce-certificate-trust")
+	bool enforceCertificateTrust = false;
+
+	@Name("service-name")
+	string serviceName = "DUB - The D package registry";
+	@Name("service-url")
+	string serviceURL = "https://code.dlang.org/";
+	@Name("service-email")
+	string serviceEmail = "noreply@rejectedsoftware.com";
+
+	@Name("mail-server") @Optional
+	string mailServer;
+	@Name("mail-server-port") @Optional
+	ushort mailServerPort;
+	@Name("mail-connection-type") @Optional
+	SMTPConnectionType mailConnectionType;
+	@Name("mail-client-name") @Optional
+	string mailClientName;
+	@Name("mail-user") @Optional
+	string mailUser;
+	@Name("mail-password") @Optional
+	string mailPassword;
+
+	@Name("administrators") @Optional
+	string[] administrators;
+
+	static AppConfig read (string path = "settings.json")
+	{
+        import std.file : exists;
+
+		if (!path.exists) return AppConfig.init;
+		auto configN = parseConfigFileSimple!AppConfig(path);
+		if (configN.isNull()) return AppConfig.init;
+		return configN.get().readEnvOverrides();
+	}
+
+	static AppConfig readString (string content, string path = "/dev/null")
+	{
+		return parseConfigString!AppConfig(content, path)
+			.readEnvOverrides();
+	}
+
+	private ref AppConfig readEnvOverrides () @safe return
+	{
+		import std.traits : getUDAs;
+
+		// Check environment variables for overrides
+		static foreach (idx; 0 .. AppConfig.tupleof.length) {{
+			alias T = typeof(this.tupleof[idx]);
+			alias uda = getUDAs!(AppConfig.tupleof[idx], Name);
+			static immutable string Name_ = uda.length ? uda[0].name :
+				__traits(identifier, AppConfig.tupleof[idx]);
+
+			auto ev = environment.get(Name_.replace("-", "_").toUpper);
+			if (ev.length)
+				this.tupleof[idx] = AppConfig.getEnvType!T(ev);
+		}}
+		return this;
+	}
+
+	static T getEnvType (T) (string envValue)
+	{
+		static if (is(T == string[]))
+			return envValue.split(',');
+		else
+			return envValue.to!T;
+	}
+}
+
+unittest
+{
+	immutable str = `{
+  "github-auth": "foo",
+  "enforce-certificate-trust": true,
+  "mail-connection-type": "startTLS",
+  "administrators": [ "Joe Bloggs", "Walter Bright", "root" ]
+}
+`;
+	auto conf = AppConfig.readString(str);
+    assert(conf.ghauth == "foo");
+    assert(conf.glauth.length == 0);
+    assert(conf.enforceCertificateTrust == true);
+    assert(conf.mailConnectionType == SMTPConnectionType.startTLS);
+    assert(conf.administrators == [ "Joe Bloggs", "Walter Bright", "root" ]);
+
+    environment["MAIL_CONNECTION_TYPE"] = "tls";
+    auto c2 = AppConfig.readString(str);
+    assert(c2.mailConnectionType == SMTPConnectionType.tls);
+}