-
Notifications
You must be signed in to change notification settings - Fork 6
/
uControlMover.pas
172 lines (154 loc) · 4.48 KB
/
uControlMover.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
unit uControlMover;
interface
uses
// Delphi
System.Types,
FMX.Forms,
FMX.Types,
FMX.Controls;
type
TSaveProperties = record
Control: TControl;
Align: TAlignLayout;
Position: TPointF;
end;
TGetMoveControlEvent = procedure(Sender: TObject; FocusedControl: TControl; var MoveControl: TControl) of object;
TControlMover = class(TObject)
private
FForm: TCommonCustomForm;
FSaveProps: TSaveProperties;
FVKBounds: TRect;
FVKVisible: Boolean;
FOnGetMoveControl: TGetMoveControlEvent;
procedure DoGetMoveControl;
function GetFocusedControlOffset(KeyboardRect: TRect): Single;
function GetStatusBarHeight: Single;
function GetViewRect: TRectF;
function FocusedControl: TControl;
procedure FormVirtualKeyboardHidden(Sender: TObject; KeyboardVisible: Boolean; const Bounds: TRect);
procedure FormVirtualKeyboardShown(Sender: TObject; KeyboardVisible: Boolean; const Bounds: TRect);
public
constructor Create(AForm: TCommonCustomForm);
procedure SlideControl;
property OnGetMoveControl: TGetMoveControlEvent read FOnGetMoveControl write FOnGetMoveControl;
end;
implementation
uses
System.SysUtils,
{$IFDEF IOS}
iOSapi.UIKit,
FMX.Platform.iOS,
iOSApi.Foundation,
{$ENDIF}
FMX.Memo;
{ TControlMover }
constructor TControlMover.Create(AForm: TCommonCustomForm);
begin
inherited Create;
FForm := AForm;
FForm.OnVirtualKeyboardShown := FormVirtualKeyboardShown;
FForm.OnVirtualKeyboardHidden := FormVirtualKeyboardHidden;
end;
procedure TControlMover.FormVirtualKeyboardHidden(Sender: TObject; KeyboardVisible: Boolean; const Bounds: TRect);
begin
FVKVisible := False;
if Assigned(FSaveProps.Control) then
begin
FSaveProps.Control.AnimateFloat('Position.Y', FSaveProps.Position.Y, 0.1);
FSaveProps.Control.Align := FSaveProps.Align;
end;
end;
procedure TControlMover.FormVirtualKeyboardShown(Sender: TObject; KeyboardVisible: Boolean; const Bounds: TRect);
begin
FVKVisible := True;
FVKBounds := Bounds;
if FocusedControl = nil then
EXIT;
DoGetMoveControl;
if Assigned(FSaveProps.Control) then
begin
FSaveProps.Control.Align := TAlignLayout.None;
FSaveProps.Position.Y := FSaveProps.Control.Position.Y;
SlideControl;
end;
end;
procedure TControlMover.DoGetMoveControl;
var
MoveControl: TControl;
begin
MoveControl := nil;
if Assigned(FOnGetMoveControl) then
FOnGetMoveControl(Self, FocusedControl, MoveControl);
FSaveProps.Control := MoveControl;
end;
function TControlMover.FocusedControl: TControl;
begin
Result := nil;
if Assigned(FForm.Focused) and (FForm.Focused.GetObject is TControl) then
Result := TControl(FForm.Focused.GetObject);
end;
function TControlMover.GetFocusedControlOffset(KeyboardRect: TRect): Single;
var
Control: TControl;
ControlPos: TPointF;
ControlHeight: Single;
Memo: TMemo;
Caret: TCaret;
ViewRect: TRectF;
begin
Result := 0;
Control := FocusedControl;
if Assigned(Control) then
begin
ControlPos := Control.LocalToAbsolute(PointF(0, 0));
ControlHeight := Control.Height;
if Control is TMemo then
begin
Memo := TMemo(Control);
Caret := Memo.Caret;
ControlPos.Y := ControlPos.Y + (Caret.Pos.Y - Memo.ViewportPosition.Y);
ControlHeight := Caret.Size.Height + 4;
end;
ViewRect := GetViewRect;
Result := (ControlPos.Y + ControlHeight + 2)
// Subtract the keyboard height from the view height to obtain the actual top of the keyboard
- ((ViewRect.Bottom - ViewRect.Top) - (KeyboardRect.Bottom - KeyboardRect.Top))
// Add the status bar height
+ GetStatusBarHeight;
if Result < 0 then
Result := 0;
end;
end;
function TControlMover.GetStatusBarHeight: Single;
{$IFDEF IOS}
begin
Result := 0;
{$IFDEF CPUARM} // i.e. on an iOS device
if TOSVersion.Check(7, 0) then
Result := TUIApplication.wrap(TUIApplication.OCClass.SharedApplication).statusBarFrame.size.height;
{$ENDIF}
end;
{$ELSE}
begin
Result := 0;
end;
{$ENDIF}
function TControlMover.GetViewRect: TRectF;
{$IFDEF IOS}
var
ARect: NSRect;
begin
ARect := WindowHandleToPlatform(FForm.Handle).View.bounds;
Result := RectF(ARect.origin.x, ARect.origin.y, ARect.size.width - ARect.origin.x, ARect.size.height - ARect.origin.y);
end;
{$ELSE}
begin
// TODO - Android
end;
{$ENDIF}
procedure TControlMover.SlideControl;
begin
if FVKVisible and Assigned(FSaveProps.Control) then
FSaveProps.Control.AnimateFloat('Position.Y', FSaveProps.Control.Position.Y - GetFocusedControlOffset(FVKBounds), 0.1);
end;
end.