-
Notifications
You must be signed in to change notification settings - Fork 0
/
install.ins
147 lines (123 loc) · 4.14 KB
/
install.ins
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
[Initial]
Message=WLAN-SG wird konfiguriert...
DefVar $CertificateId$
DefVar $CurrentLogLevel$
DefVar $ExitCode$
DefVar $IServHostname$
DefVar $Password$
DefVar $SchoolNumber$
DefStringList $Result$
; This script generates an XML WLAN profile according to the specification:
; http://msdn.microsoft.com/en-us/library/windows/desktop/ms706965(v=vs.85).aspx
;
; Windows XP:
; No longer supported!
;
; Windows 7/8/10:
; Windows 7/8/10 can read the XML file natively with netsh wlan.
[Actions]
ShowBitmap "%ScriptPath%\logo.png" "WLAN-SG einrichten"
Sub_GetVars
Sub_ValidateConfig
Sub_RemovePreviousCerts
Files_Copy
WinBatch_SetACL
Winbatch_ImportCert /RunElevated
Sub_Setup
Files_Cleanup
[Sub_ValidateConfig]
Set $CurrentLogLevel$ = GetLoglevel
SetLogLevel=4
Set $Result$ = GetReturnListFromSection("opsiservicecall_GetCertificatePassword")
Set $Password$ = TakeString("0", $Result$)
SetConfidential $Password$
SetLogLevel=$CurrentLogLevel$
;sanity checks
if $CertificateId$ = ""
LogError "Fatal: no Certificate ID found. Aborting."
IsFatalError
endif
if $Password$ = ""
LogError "Fatal: no certificate password given! Aborting."
IsFatalError
endif
[Sub_GetVars]
Set $Result$ = GetReturnListFromSection("opsiservicecall_GetCertificateId")
Set $CertificateId$ = TakeString("0", $Result$)
if $CertificateId$ = ""
Set $Result$ = GetReturnListFromSection("opsiservicecall_GetInventoryNumber")
Set $CertificateId$ = TakeString("0", $Result$)
endif
Set $IServHostname$ = Lower(Trim(TakeString(0, GetReturnListFromSection("opsiservicecall_GetHostname"))))
Set $SchoolNumber$ = TakeString(0, PowershellCall("([regex]'^(\d+)').Matches('" + $CertificateId$ + "').Value"))
comment "Certifcate ID is: " + $CertificateId$
comment "School number is: " + $SchoolNumber$
[Sub_RemovePreviousCerts]
PowershellCall("Get-ChildItem Cert:\LocalMachine\My | Where-Object { $_.Subject -match '" + $SchoolNumber$ + "' } | Remove-Item")
[Files_Copy]
copy "\\$IServHostname$\appdata\%installingProdName%\certificates\$CertificateId$.pfx" "%SystemDrive%\tmp"
copy "%ScriptPath%\wlan-profile.xml" "%SystemDrive%\tmp"
[WinBatch_SetACL]
; If this script fails, we don't want to leave a world-readable profile behind.
;
; remove inherited ACEs:
; -actn setprot -op "dacl:p_nc;sacl:p_nc"
; add ACE for SYSTEM
; -actn ace -ace "n:S-1-5-18;p:full"
; add ACE for Administrators:
; -ace "n:S-1-5-32-544;p:full"
"%ScriptPath%\SetACL.exe" -on "%SystemDrive%\tmp\wlan-profile.xml" -ot file -actn setprot -op "dacl:p_nc;sacl:p_nc" -actn ace -ace "n:S-1-5-18;p:full" -ace "n:S-1-5-32-544;p:full"
"%ScriptPath%\SetACL.exe" -on "%SystemDrive%\tmp\$CertificateId$.pfx" -ot file -actn setprot -op "dacl:p_nc;sacl:p_nc" -actn ace -ace "n:S-1-5-18;p:full" -ace "n:S-1-5-32-544;p:full"
[Winbatch_ImportCert]
%System%\certutil.exe -p $Password$ -importpfx "%SystemDrive%\tmp\$CertificateId$.pfx"
[Sub_Setup]
if CompareDotSeparatedNumbers(GetMsVersionInfo, ">=", "6.1")
; Windows 7/8.1/10
DosInAnIcon_netsh
Sub_HandleExitCode
DosInAnIcon_connect
; No handle exit code as connect may fail if device is not in reach of AP
else
LogError "Unsupported OS!"
IsFatalError
endif
[DosInAnIcon_netsh]
netsh wlan add profile filename="%SystemDrive%\tmp\wlan-profile.xml" user=all
[DosInAnIcon_connect]
netsh wlan connect name=WLAN-SG
set loopinc=0
:pingloop
set /a loopinc=%loopinc%+1
if "%loopinc%"=="15" goto pingloopend
timeout 1 >NUL
ping -n 1 $IServHostname$ | find "TTL=" || goto :pingloop
:pingloopend
[Sub_HandleExitCode]
; check return code
Set $ExitCode$ = GetLastExitCode
comment "GetLastExitCode: " + $ExitCode$
if not($ExitCode$ = "0")
LogError "Fatal: setup returned exit code " + $ExitCode$
IsFatalError
endif
[Files_Cleanup]
delete "%SystemDrive%\tmp\$CertificateId$.pfx"
delete "%SystemDrive%\tmp\wlan-profile.xml"
[opsiservicecall_GetInventoryNumber]
"method":"collect_wlan_mac_inventoryNumber"
"params":[]
[opsiservicecall_GetCertificateId]
"method":"host_config_getValue"
"params":[
"stadthh_wlansg_certificate_id"
]
[opsiservicecall_GetCertificatePassword]
"method":"host_config_getValue"
"params":[
"stadthh_wlansg_certificate_password"
]
[opsiservicecall_GetHostname]
"method":"iserv_cfg"
"params":[
"Hostname"
]