-
Notifications
You must be signed in to change notification settings - Fork 3
/
build.gradle
154 lines (127 loc) · 3.39 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
plugins {
id 'java-library'
id 'maven-publish'
// To manage included native libraries
id 'org.openjfx.javafxplugin' version '0.1.0'
}
ext.moduleName = 'qupath.extension.bioimageio'
ext.qupathVersion = gradle.ext.qupathVersion
ext.qupathJavaVersion = 17
base {
description = 'QuPath extension to use the Bioimage Model Zoo (bioimage.io)'
version = "0.2.0-SNAPSHOT"
group = 'io.github.qupath'
}
// Looks redundant to include this here and in settings.gradle,
// but helps overcome some gradle trouble when including this as a subproject
// within QuPath itself (which is useful during development).
repositories {
// Add this if you need access to dependencies only installed locally
// mavenLocal()
mavenCentral()
// Add scijava - which is where QuPath's jars are hosted
maven {
url "https://maven.scijava.org/content/repositories/releases"
}
maven {
url "https://maven.scijava.org/content/repositories/snapshots"
}
}
dependencies {
implementation "io.github.qupath:qupath-gui-fx:${qupathVersion}"
implementation libs.bioimageio.spec
// These are included in QuPath distributions
implementation libs.bundles.logging
implementation libs.snakeyaml
implementation libs.controlsfx
testImplementation libs.junit
testRuntimeOnly libs.junit.platform
}
processResources {
from ("${projectDir}/LICENSE") {
into 'META-INF/licenses/'
}
}
tasks.register("copyDependencies", Copy) {
description "Copy dependencies into the build directory for use elsewhere"
group "QuPath"
from configurations.default
into 'build/libs'
}
/*
* Ensure Java compatibility
*/
java {
toolchain {
languageVersion = JavaLanguageVersion.of(qupathJavaVersion)
}
if (project.properties['sources'])
withSourcesJar()
if (project.properties['javadocs'])
withJavadocJar()
}
/*
* Manifest info
*/
jar {
manifest {
attributes("Implementation-Title": project.name,
"Implementation-Version": archiveVersion,
"Automatic-Module-Name": "io.github." + moduleName)
}
}
/*
* Create javadocs for all modules/packages in one place.
* Use -PstrictJavadoc=true to fail on error with doclint (which is rather strict).
*/
tasks.withType(Javadoc) {
options.encoding = 'UTF-8'
def strictJavadoc = findProperty('strictJavadoc')
if (!strictJavadoc) {
options.addStringOption('Xdoclint:none', '-quiet')
}
}
/*
* Set encoding
*/
tasks.named('compileJava') {
options.encoding = 'UTF-8'
}
/*
* Avoid 'Entry .gitkeep is a duplicate but no duplicate handling strategy has been set.'
* when using withSourcesJar()
*/
tasks.withType(org.gradle.jvm.tasks.Jar) {
duplicatesStrategy = DuplicatesStrategy.INCLUDE
}
tasks.named('test') {
useJUnitPlatform()
}
publishing {
repositories {
maven {
name = "SciJava"
def releasesRepoUrl = uri("https://maven.scijava.org/content/repositories/releases")
def snapshotsRepoUrl = uri("https://maven.scijava.org/content/repositories/snapshots")
// Use gradle -Prelease publish
url = project.hasProperty('release') ? releasesRepoUrl : snapshotsRepoUrl
credentials {
username = System.getenv("MAVEN_USER")
password = System.getenv("MAVEN_PASS")
}
}
}
publications {
mavenJava(MavenPublication) {
from components.java
pom {
licenses {
license {
name = 'Apache License v2.0'
url = 'http://www.apache.org/licenses/LICENSE-2.0'
}
}
}
}
}
}