Eliminating redundant choice points in ints_median_index/3

[jjtolton]

I am struggling to remove the redundant choice point in ints_median_index/3:

:- use_module(library(lists)).
:- use_module(library(reif)).
:- use_module(library(debug)).

ints_median_index(Ints, Median, Index) :-
        length(Ints, N),
        Index #= N // 2,
        Index1 #= Index + 1,
        if_(clpz_t( N mod 2 #= 0),
            (   nth1(A, Ints, Index),
                nth1(B, Ints, Index1),
                Median is (A + B) / 2
            ),
            nth1(Median, Ints, Index1)
           ).
        
        

?- ints_median_index([1, 2, 3], Median, Index).
%@    Median = 2, Index = 1
%@ ;  false.

?- ints_median_index([1, 2, 3, 4], Median, Index).
%@    Median = 2.5, Index = 2
%@ ;  false.

I have a suspicion this has something to do with argument indexing, because when I use $/1 to do debugging, it seems like the body of the predicate is only run once, so I'm not sure where the redundant choice point is coming from! Does anyone have any suggestions?

[triska]

Currently, we get:

?- ints_median_index([0], Median, Index).
   false, unexpected.
?- ints_median_index([0,1], Median, Index).
   false, unexpected.
?- ints_median_index([0,1,4], Median, Index).
   false, unexpected.

[jjtolton]

So strange!!

?- ints_median_index([0,1,2], Median, Index).
%@    Median = 3, Index = 1.

?- ints_median_index([0,1,3], Median, Index).
%@    false.

?- ints_median_index([1,2,3], Median, Index).
%@    Median = 2, Index = 1
%@ ;  false.

Great catch!

[jjtolton]

Whoops... I was confusing the order of the arguments for nth1/3 🤦

:- use_module(library(lists)).
:- use_module(library(reif)).
:- use_module(library(debug)).
:- use_module(library(format)).

ints_median_index(Ints, Median, Index) :-
        length(Ints, N),
        Index #= N // 2,
        Index1 #= Index + 1,
        if_(clpz_t( (N mod 2) #= 0),
            (   nth1(Index, Ints, A),
                nth1(Index1, Ints, B),
                Median is (A + B) / 2
            ),
            nth1(Index1, Ints, Median)
           ).
        
        
?- ints_median_index([1, 2, 3], Median, Index).
%@    Median = 2, Index = 1.

?- ints_median_index([1, 2, 3, 4], Median, Index).
%@    Median = 2.5, Index = 2.

?- ints_median_index([0], Median, Index).
%@    Median = 0, Index = 0.

?- ints_median_index([0,1], Median, Index).
%@    Median = 0.5, Index = 1.

?- ints_median_index([0,1,4], Median, Index).
%@    Median = 1, Index = 1.

?- ints_median_index([1,2,3], Median, Index).
%@    Median = 2, Index = 1.

?- ints_median_index([0,1,2], Median, Index).
%@    Median = 1, Index = 1.

?- ints_median_index([0,1,3], Median, Index).
%@    Median = 1, Index = 1.

?- ints_median_index([1,2,5], Median, Index).
%@    Median = 2, Index = 1.

It would be interesting to speculate why I wasn't able to catch that until @triska pointed those examples out!

[triska]

You can use (*)/1 to generalize your program, so that you find a minimal fragment that still fails unintentionally for a given query. The remaining fragment contains a mistake.