-
Notifications
You must be signed in to change notification settings - Fork 0
/
SPIRO_Macros.ijm
2876 lines (2651 loc) · 111 KB
/
SPIRO_Macros.ijm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* GLOBAL VARIABLES
* ================
*/
// GENERAL VARIABLES USED BY THE 3 MACROS
var maindir; // main directory: user-selected directory containing SPIRO-acquired images
var listInmaindir; // list of files or directories in the main directory
var resultsdir; // results directory: all macro-generated results will be saved here
var platedir; // plate directories in main directory
var listInplatedir; // number of time points
var resultsdir; // results subdir of main directory
var ppdir; // preprocessing subdir
// alternate types of macro run
var DEBUG = false; // hold down ctrl during macro start to keep non-essential intermediate output files
var freshstart = false; // hold down shift key during macro start to delete all previous data
var selfaware = false; // rootgrowth: alt key during macro start
var overlay = false; // rootgrowth: dependent on DEBUG: prompts user on choice whether to overlay skeletons
var RSCtracking = true; //rootgrowth: dependent on DEBUG: prompts user on choice whether to track RSC dynamically, otherwise use seed position as RSC
// PREPROCESSING-SPECIFIC VARIABLES
var runRegistration // user choice on whether to run registration
var batchsize = 350;
var batched; // if number of time points exceeds batchsize, preprocessing will be carried out in batches
var rbatched = 1;
var rNonbatched = 2;
// GERMINATION-SPECIFIC VARIABLES
var germdir; // directory under resultsdir where germination macro output is contained
// ROOT GROWTH-SPECIFIC VARIABLES
var rootgrowthdir; // directory under resultsdir where germination macro output is contained
var listInrootgrowthdir; // list of directories and files under rootgrowthdir
var step; // current step
var fullplatearray; // array of plates to be processed
var fullgrouparray; // array of groups to be processed
var totalnoOfgroups; //total number of groups to process
var platesToprocess; // if macro resumes from previous run, array of plates to be continued with
var groupsToprocess; // if macro resumes from previous run, array of groups to be continued with
var lengthOfgroupsToprocess; // if macro resumes from previous run, size of array of groups to process
var resumestep; // step to resume from
var methodinput = "MaxEntropy";
var cleanwithfirstslice = 1;
/*
* ---------------------
*/
macro "SPIRO_Preprocessing" {
/*** The preprocessing macro sets scale and processes images to optimize downstream analysis (germination or root growth) ***
*
* The workflow is as follows:
* first detect if batch needed, then get user choice
* if batch not needed, crop, greench, and register in one go (no intermediate files)
* if batch needed, separate into segments during run image sequence, save directly in preprocessing (no new folder)
* use _batchN to denote batch, and plateN can be used to identify it
* Crop and GreenCh: run as usual on the list of files
* crop then immediately greenCh to make plateN_batchN_greenCh
* Register: Open greenCh and add first image to each stack (to prevent jumps between batches), save each batch
* At the end, merge all plateN_batchN preprocessed to make plateN_preprocessed
*/
/*
* Check whether the required plugins TurboReg and MultiStackReg are installed
* ---------------------------------------------------------------------------
*/
List.setCommands;
if(List.get("TurboReg ")!="") {
turboreginstalled = true;
} else {
turboreginstalled = false;
}
if(List.get("MultiStackReg")!="") {
multistackreginstalled = true;
} else {
multistackreginstalled = false;
}
if (!turboreginstalled || !multistackreginstalled) {
Dialog.create("Plugin not found");
Dialog.addMessage("Plugins TurboReg and/or MultiStackReg not found. Please refer to the SPIRO manual for installation instructions.");
Dialog.addCheckbox("I understand.", false);
Dialog.show();
usercheck = Dialog.getCheckbox();
if (usercheck == true)
exit;
}
print("=================================================\n"+
"Welcome to the companion macro of SPIRO for preprocessing!\n" +
"=================================================");
selectWindow("Log");
/* Create and/or define working directories
* ----------------------------------------
*/
showMessage("Welcome to the companion macro of SPIRO for preprocessing!\n" +
"Please locate and open your experiment folder containing SPIRO-acquired images.\n" +
"---------\n" +
"Alternative types of run (hold down then press OK):\n" +
"SHIFT = Fresh Start mode, all data from any previous run will be deleted\n" +
"CTRL = Debug mode, batch size for drift correction can be changed.\n");
wait(1000);
if (isKeyDown("control"))
DEBUG = getBoolean("CTRL key pressed. Run macro in debug mode? Batch size for drift correction can be changed.");
if (isKeyDown("shift"))
freshstart = getBoolean("SHIFT key pressed. Run macro in Fresh Start mode? This will delete all data from the previous run.");
maindir = getDirectory("Choose a Directory");
listInmaindir = getFileList(maindir);
resultsdir = maindir + "Results" + File.separator; // all output is contained here
if (!File.isDirectory(resultsdir))
File.makeDirectory(resultsdir);
ppdir = resultsdir + "Preprocessing" + File.separator; // output from the proprocessing macro is here
if (!File.isDirectory(ppdir))
File.makeDirectory(ppdir);
// safeguard against processing non-plate (user-introduced) file
for (fileindex = 0; fileindex < listInmaindir.length; fileindex++) {
if (indexOf(listInmaindir[fileindex], "plate") == -1)
listInmaindir = Array.deleteValue(listInmaindir, listInmaindir[fileindex]);
}
/*
* Get user choice on drift correction
* ---------------------------------------
*/
Dialog.create("Drift Correction");
Dialog.addMessage("Would you like to carry out drift correction (registration)?\n" +
"Please note that this step may take up a lot of time and RAM for large datasets.\n" +
"Batch size may be reduced in DEBUG mode for lower RAM requirement.");
dialogchoices = newArray("Yes", "No");
Dialog.addChoice("", dialogchoices);
Dialog.show;
regUserInput = Dialog.getChoice();
if (regUserInput == "Yes") {
runRegistration = true;
} else {
runRegistration = false;
}
if (DEBUG && runRegistration)
Dialog.create("(DEBUG) Drift Correction Batch Size");
Dialog.addMessage("Drift correction (registration) may be carried out in smaller batches of the image stack to reduce RAM requirement.\n"
+ "Please set desired batch size");
Dialog.addNumber("Batch size", batchsize);
/* Main chunk of code - all run functions are here
* -----------------------------------------------
*/
if (freshstart)
deleteOutputPP();
scale();
batch();
cropnGreenCh();
if (runRegistration) {
if (batched)
register(rbatched);
if (!batched)
register(rNonbatched);
} else {
noReg();
print("Step 4/4 Drift correction skipped due to user choice");
}
deleteOutputPP();
list = getList("window.titles");
list = Array.deleteValue(list, "Log");
for (i=0; i<list.length; i++) {
winame = list[i];
selectWindow(winame);
run("Close");
}
print("\nPreprocessing is complete.");
selectWindow("Log");
/* ----------------------------------------------
* Lines below this are functions and their descriptions
*/
function scale() {
/* The scale() function first attempts to automatically find out the scale based on the approximate location of the 1cm scale bar printed on SPIRO
* this is done by masking then filtering objects based on their width-to-height (WtH) ratio (the scale bar should be something longer horizontally)
* an additional filter: potential scale bar must be more than 150 pixels long / wide ( to prevent small noise from matching WtH ratio.
* if only a single object matches the potential scale bar, this is highlighted and confirmation from the user is obtained
* If multiple or no objects match scale bar WtH ratio, or the automatically detected scale bar is wrong
* the user is prompted to draw a line corresponding to the length of the scale bar
*/
if (is("Batch Mode"))
setBatchMode(false);
print("Step 1/4 Setting scale...");
plate1dir = maindir + listInmaindir[0]; // only first image of first plate needed to set scale
listInplate1dir = getFileList(plate1dir);
Array.sort(listInplate1dir);
img1 = listInplate1dir[0];
open(plate1dir + img1);
run("Set Scale...", "distance=1 known=1 unit=pixel"); //remove scale
run("Set Measurements...", "area bounding display redirect=None decimal=3");
// get approximate location of scale bar
setTool("line");
xapprox = getWidth()/5*4;
xmax = getWidth();
yapprox = getHeight()/5*4;
ymax = getHeight();
widthapprox = xmax - xapprox;
heightapprox = ymax - yapprox;
/*
makeRectangle(xapprox, yapprox, widthapprox, heightapprox);
run("Duplicate...", "use");
rename("tempscalebar");
slicelabel = getInfo("slice.label");
// thresholding for scale bar
run("8-bit");
run("Gaussian Blur...", "sigma=7");
if (indexOf(slicelabel, "day") > -1 ) {
run("Subtract Background...", "rolling=90");
} else {
run("Subtract Background...", "rolling=90 light");
}
roiManager("reset");
setAutoThreshold("Default");
setOption("BlackBackground", false);
run("Convert to Mask");
// filter potential objects by width to height ratio
run("Create Selection");
roiManager("Split");
roicount = roiManager("count");
for (roino = 0; roino < roicount; roino ++) {
roiManager("select", roino);
Roi.getBounds(roix, roiy, roiw, roih);
whratio = roiw/roih;
if (whratio < 2.5 || whratio > 3.5) {
roiManager("select", roino);
roiManager("delete");
roino -= 1;
roicount -= 1;
}
}
// filter potential objects by unscaled width
roicount = roiManager("count");
if (roicount > 1) {
for (roino = 0; roino < roicount; roino ++) {
roiManager("select", roino);
Roi.getBounds(roix, roiy, roiw, roih);
if (roiw < 150) { // scale bar should be at least 150 pixels long
roiManager("select", roino);
roiManager("delete");
roino -= 1;
roicount -= 1;
}
}
}
// if only one object matches = potential scale bar, check with user
if (roicount == 1) {
scalefail = false;
roiManager("select", 0);
Roi.getBounds(roix, roiy, roiw, roih);
makeLine(roix, roiy + roih/2, roix + roiw, roiy + roih/2);
Dialog.create("User-guided scale setting");
choicearray = newArray("Yes", "No");
Dialog.addChoice("Does the line drawn correspond to the scale bar?", choicearray);
Dialog.show();
userchoice = Dialog.getChoice();
} else {
scalefail = true;
userchoice = "none";
}
// if multiple or no objects match + auto-detected scale bar is wrong, prompt user to draw line corresponding to scale bar
if (userchoice == "no" || scalefail) {
close("tempscalebar");
selectWindow(img1);
run("Select None");
run("Set... ", "zoom=50 x=["+xapprox+"] y=["+yapprox+"]");
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("Automatic scale detection unsucessful");
Dialog.addMessage("Based on the scale bar, draw a straight line corresponding to 1cm\n." +
"Holding down SHIFT helps in keeping line horizontal");
Dialog.addCheckbox("Scale bar corresponding to 1cm has been drawn", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
} else {
close("tempscalebar");
selectWindow(img1);
makeLine(xapprox + roix, yapprox + roiy, xapprox + roix + roiw, yapprox + roiy);
}
*/
run("Set... ", "zoom=50 x=["+xapprox+"] y=["+yapprox+"]");
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("Scale");
Dialog.addMessage("Based on the scale bar, draw a straight line corresponding to 1 cm\n." +
"Holding down SHIFT helps in keeping the line horizontal.");
Dialog.addCheckbox("Scale bar corresponding to 1 cm has been drawn", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
// measures line length (auto-detected or user-selected) and sets scale
run("Set Measurements...", "area bounding display redirect=None decimal=3");
run("Measure");
Table.rename("Results", "scalebar");
length = getResult('Length', nResults - 1);
run("Set Scale...", "distance=" + length + " known=1 unit=cm global");
// based on scale bar, get coordinates to crop so that only SPIRO-relevant part of image is present
nR = Table.size("scalebar");
bx = Table.get("BX", nR - 1, "scalebar");
bx = parseFloat(bx);
by = Table.get("BY", nR - 1, "scalebar");
by = parseFloat(by);
length = Table.get("Length", nR - 1, "scalebar");
xmid = (bx + length/2);
xmid = bx + 0.5*length;
xmid = parseFloat(xmid);
dx = 13;
dy = 10.5;
toUnscaled(dx, dy);
x1 = xmid - dx;
y1 = by - dy;
width = 14;
height = 12.5;
toUnscaled(width, height);
roiManager("reset");
makeRectangle(x1, y1, width, height);
roiManager("add");
run("Original Scale"); // zoom out
userconfirm = false;
selectWindow(img1);
while (!userconfirm) {
Dialog.createNonBlocking("Crop selection");
Dialog.addMessage("If needed, please correct the selected area for cropping by updating ROI in ROI manager, then click OK.");
Dialog.addCheckbox("ROI is correct", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
roiManager("select", 0);
getBoundingRect(xcrop, ycrop, wcrop, hcrop);
Table.create("cropcoordinates");
Table.set("xcrop", 0, xcrop, "cropcoordinates");
Table.set("ycrop", 0, ycrop, "cropcoordinates");
Table.set("wcrop", 0, wcrop, "cropcoordinates");
Table.set("hcrop", 0, hcrop, "cropcoordinates");
close();
selectWindow("scalebar");
run("Close");
}
function batch() {
/* If the number of time points in the experiment (alternatively, the number of images in the stack) exceeds batchsize (default 350)
* images are separated into batches for processing, as we found that this can help in reducing RAM requirement
*/
if (!is("Batch Mode"))
setBatchMode(true);
print("\nStep 2/4 Converting images into stacks..." +
"\nIt may look like nothing is happening, please be patient.");
selectWindow("Log");
for (plateno = 0; plateno < listInmaindir.length; plateno ++) {
platefolder = listInmaindir[plateno];
platedir = maindir + platefolder;
platename = File.getName(platedir);
listInplatedir = getFileList(platedir);
Array.sort(listInplatedir);
numtp = listInplatedir.length; // number of time points
print("Processing " + platename);
if (numtp > batchsize) {
batched = true;
if (plateno == 0)
print(numtp + " time points detected. Separating files into batches of " + batchsize + " images at a time...");
selectWindow("Log");
numloops = numtp / batchsize; // number of loops to make batches
rnl = floor(numloops) + 1; //returns closest integer rounded down
for (batchloop = 0; batchloop < numloops; batchloop ++) {
initial = batchloop * batchsize;
if (batchloop != numloops - 1) {
run("Image Sequence...", "open=[" + platedir + listInplatedir[0] + "] number=" + batchsize +
" starting=" + initial+1 + " convert_to_rgb use");
saveAs("Tiff", ppdir + platename + "_batch" + batchloop+1 + ".tif");
close();
} else { //on last loop
lastno = numtp - initial + 1; //open only the number of images left
run("Image Sequence...", "open=[" + platedir + listInplatedir[0] + "] number=" + lastno +
" starting=" + initial+1 + " convert_to_rgb use");
saveAs("Tiff", ppdir + platename + "_batch" + batchloop+1 + ".tif");
close();
}
}
} else {
batched = false;
if (plateno == 0)
print(numtp + " time points detected. Preprocessing will be carried out in a single batch.");
selectWindow("Log");
run("Image Sequence...", "open=[" + platedir + listInplatedir[0] + "] number=" + numtp +
" starting=1 convert_to_rgb use");
saveAs("Tiff", ppdir + platename + ".tif");
close();
}
}
}
function cropnGreenCh() {
/* Use the crop coordinates obtained in the scale() function to crop away unnecessary background
* Saves the green channel 8-bit image, as we found that it gives the clearest image of roots, and with least noise from Moire patterns
*/
if (!is("Batch Mode"))
setBatchMode(true);
print("\nStep 3/4 Cropping off unnecessary background and splitting into green channel..." +
"\nIt may look like nothing is happening, please be patient.");
listInppdir = getFileList(ppdir);
Array.sort(listInppdir);
for (fileno = 0; fileno < listInppdir.length; fileno ++) {
open(ppdir + listInppdir[fileno]);
ppstack = getTitle();
if (indexOf(ppstack, "GreenCh") < 0 && indexOf(ppstack, "preprocessed") < 0) {
ppstackname = File.nameWithoutExtension;
print("Processing " + ppstackname);
// Crop based on position of scale bar (with user checking in scale step)
xcrop = Table.get("xcrop", 0, "cropcoordinates");
ycrop = Table.get("ycrop", 0, "cropcoordinates");
wcrop = Table.get("wcrop", 0, "cropcoordinates");
hcrop = Table.get("hcrop", 0, "cropcoordinates");
makeRectangle(xcrop, ycrop, wcrop, hcrop);
run("Crop");
// Split into green channel
selectWindow(ppstack);
stacksize = nSlices(); //total number of slices
slicelabelsarray = newArray(stacksize); //an array to be filled with all slicelabels
for (sliceno = 1; sliceno <= stacksize; sliceno ++) {
setSlice(sliceno);
slicelabel = getInfo("slice.label");
slicelabelsarray[sliceno-1] = slicelabel;
}
run("Split Channels");
imglist = getList("image.titles");
for (img = 0; img < imglist.length; img ++) {
imgname = imglist[img];
if (indexOf(imgname, "red") > 0 ) {
selectWindow(imgname);
close();
}
if (indexOf(imgname, "green") > 0) {
selectWindow(imgname);
for (sliceno = 1; sliceno <= stacksize; sliceno ++) {
setSlice(sliceno);
slicelabel = slicelabelsarray[sliceno-1];
setMetadata("Label", slicelabel);
}
selectWindow(imgname);
rename(ppstack);
}
if (indexOf(imgname, "blue") > 0) {
selectWindow(imgname);
close();
}
}
saveAs("Tiff", ppdir + ppstackname + "_GreenCh.tif");
close();
filedelete = File.delete(ppdir + ppstackname + ".tif");
} else {
close();
}
if (fileno == listInppdir.length - 1) {
selectWindow("cropcoordinates");
run("Close");
}
}
}
function register(rMode) {
/* Drift correction - dependent on MultiStackReg which is in turn dependent on TurboReg
* Registration is needed because SPIRO cube may not always perfectly align with camera view, and user may have moved the plate between time points of image capture
* rMode "registration mode" defines whether the function runs on a single stack, or multiple batches of stacks to be merged at the end
*/
if (!is("Batch Mode"))
setBatchMode(true);
print("\nStep 4/4 Correcting drift...\nIt may look like nothing is happening, please be patient.");
listInppdir = getFileList(ppdir);
Array.sort(listInppdir);
listInppdirlength = listInppdir.length;
if (rMode == rNonbatched) {
for (plateno = 0; plateno < listInppdir.length; plateno ++) {
grplatefile = listInppdir[plateno]; // green channel image
grplatename = File.getName(ppdir + grplatefile);
if (indexOf(grplatename, "GreenCh") > -1) {
pfsplit = split(grplatename, "_");
platename = pfsplit[0];
print("Processing " + platename);
open(ppdir + grplatename);
run("Subtract Background...", "rolling=30 stack"); // makes edges stand out more, to make registration more accurate
tfn = ppdir + "Transformation";
run("MultiStackReg", "stack_1=" + grplatename + " action_1=Align file_1=" + tfn +
" stack_2=None action_2=Ignore file_2=[] transformation=Translation save");
close(grplatename);
open(ppdir + grplatename);
run("MultiStackReg", "stack_1=" + grplatename + " action_1=[Load Transformation File] file_1=" + tfn +
" stack_2=None action_2=Ignore file_2=[] transformation=[Translation]");
saveAs("Tiff", ppdir + platename + "_preprocessed.tif");
close();
filedelete = File.delete(ppdir + grplatename);
}
}
}
if (rMode == rbatched) {
listInppdir = getFileList(ppdir);
Array.sort(listInppdir);
listInppdirlength = listInppdir.length;
for (plateno = 0; plateno < listInmaindir.length; plateno ++) {
platemain = listInmaindir[plateno];
platename = File.getName(maindir + platemain);
print("Processing " + platename);
// to get plate name without getting distracted by batchN
batchfilearray = newArray(listInppdirlength);
for (fileno = 0; fileno < listInppdirlength; fileno ++) {
filename = listInppdir[fileno];
if (indexOf(filename, platename) > -1 && indexOf(filename, "batch") > -1) {
batchfilearray[fileno] = filename;
}
}
for (arrayindex = 0; arrayindex < listInppdirlength; arrayindex ++) {
if (batchfilearray[arrayindex] == 0) {
batchfilearray = Array.deleteIndex(batchfilearray, arrayindex);
listInppdirlength -= 1;
arrayindex -= 1;
}
}
for (batchno = 1; batchno < batchfilearray.length+1 ; batchno ++) {
open(ppdir + platename + "_batch" + batchno + "_GreenCh.tif");
batchsubstack = getTitle();
if (batchno == 1) {
setSlice(1);
run("Duplicate...", "use");
rename("firstslice");
}
selectWindow("firstslice");
run("Duplicate...", "use");
rename("tempfirstslice");
run("Concatenate...", " image1=tempfirstslice image2=["+ batchsubstack +"]"); //stick first slice to start of each batch to enable better registration
rename("batchsubstackSB");
run("Subtract Background...", "rolling=30 stack");
tfn = ppdir + "Transformation";
run("MultiStackReg", "stack_1=batchsubstackSB action_1=Align file_1=" + tfn +
" stack_2=None action_2=Ignore file_2=[] transformation=Translation save");
close("batchsubstackSB");
open(ppdir + batchsubstack);
// stick first slice to start of each batch to prevent jump in positions between batches
selectWindow("firstslice");
run("Duplicate...", "use");
rename("tempfirstslice");
run("Concatenate...", " image1=tempfirstslice image2=["+ batchsubstack +"]");
rename(batchsubstack);
run("MultiStackReg", "stack_1=" + batchsubstack + " action_1=[Load Transformation File] file_1=" + tfn +
" stack_2=None action_2=Ignore file_2=[] transformation=[Translation]");
run("Slice Remover", "first=1 last=1 increment=1"); //remove temporary first slice
saveAs("Tiff", ppdir + platename + "_batch" + batchno + "_preprocessed.tif");
close();
filedelete = File.delete(ppdir + batchsubstack);
}
batch1filedir = ppdir + platename + "_batch1_preprocessed.tif";
open(batch1filedir);
batch1stack = getTitle();
for (batchno = 2; batchno < batchfilearray.length+1; batchno++) {
batchNfiledir = ppdir + platename + "_batch" + batchno + "_preprocessed.tif";
open(batchNfiledir);
batchNstack = getTitle();
if (batchno == 2) {
run("Concatenate...", " image1=["+ batch1stack +"] image2=["+ batchNstack +"]");
concatbatches = getTitle();
} else {
run("Concatenate...", " image1=["+ concatbatches +"] image2=["+ batchNstack +"]");
}
}
saveAs("Tiff", ppdir + platename + "_preprocessed.tif");
close();
selectWindow("firstslice");
close();
}
}
}
function noReg() {
listInppdir = getFileList(ppdir);
for (ppfileno = 0; ppfileno < listInppdir.length; ppfileno ++) {
ppfilename = listInppdir[ppfileno];
if (indexOf(ppfilename, "GreenCh") > -1) {
pnsplit = split(ppfilename, "_");
platename = pnsplit[0];
platenamepreproc = platename + "_preprocessed.tif";
File.rename(ppdir + ppfilename, ppdir + platenamepreproc);
}
}
}
function deleteOutputPP() {
print("Deleting intermediate files...");
listInppdir = getFileList(ppdir);
for (ppfileno = 0; ppfileno < listInppdir.length; ppfileno ++) {
ppfilename = listInppdir[ppfileno];
if (indexOf(ppfilename, "batch") > -1)
filedelete = File.delete(ppdir + ppfilename);
if (indexOf(ppfilename, "GreenCh") > -1)
filedelete = File.delete(ppdir + ppfilename);
}
if (freshstart) {
print("Fresh start: deleting output from any previous run");
for (ppfileno = 0; ppfileno < listInppdir.length; ppfileno ++) {
ppfilename = listInppdir[ppfileno];
filedelete = File.delete(ppdir + ppfilename);
}
freshstart == false;
}
}
}
macro "SPIRO_Germination" {
/*** The germination macro takes a stack of preprocessed SPIRO-acquired images, prompts the user to select groups of seeds for analysis,
** then a mask is created for the seeds, and the perimeter of the objects in the mask are measured and recorded
* to be used as a proxy for germination analysis in R
*/
print("======================================================\n"+
"Welcome to the companion macro of SPIRO for germination analysis!\n" +
"======================================================");
selectWindow("Log");
showMessage("Welcome to the companion macro of SPIRO for germination analysis!\n" +
"Please locate and open your experiment folder containing preprocessed data.\n" +
"---------\n" +
"Alternative types of run (hold down then press OK):\n" +
"SHIFT = Fresh Start mode, all data from any previous run will be deleted\n" +
"CTRL = DEBUG mode, seed detection parameters can be modified");
wait(1000);
freshstart = 0;
if (isKeyDown("shift"))
freshstart = getBoolean("SHIFT key pressed. Run macro in Fresh Start mode? This will delete all data from the previous run.");
if (isKeyDown("control"))
DEBUG = getBoolean("CTRL key pressed. run macro in DEBUG mode? This enables modification of seed detection parameters.");
/* Create and/or define working directories
* ----------------------------------------
*/
maindir = getDirectory("Choose a Directory");
resultsdir = maindir + "Results" + File.separator; // all output is contained here
ppdir = resultsdir + "Preprocessing" + File.separator; // output from the proprocessing macro is here
germdir = resultsdir + "Germination" + File.separator; // output from this macro will be here
if (!File.isDirectory(germdir))
File.makeDirectory(germdir);
listInppdir = getFileList(ppdir);
listIngermdir = getFileList(germdir);
/* Main chunk of code - all run functions are here
* -----------------------------------------------
*/
if (freshstart)
deleteOutputGM();
cropGroupsGM();
seedAnalysisGM();
print("\nGermination analysis is complete.");
selectWindow("Log");
/* ----------------------------------------------
* Lines below this are functions and their descriptions
*/
function cropGroupsGM() {
/* prompts user to make a substack, to make data size smaller by excluding time points after all or most seeds have germinated
* then prompts user to draw ROIs around groups of seeds to be analyzed
*/
print("Step 1/2. Creating selected groups");
for (ppdirno = 0; ppdirno < listInppdir.length; ppdirno ++) { // main loop through plates
if (indexOf (listInppdir[ppdirno], "preprocessed") >= 0) { // to avoid processing any random files in the folder
platefile = listInppdir [ppdirno];
fnsplit = split(platefile, "_");
platename = fnsplit[0];
platefolder = germdir + File.separator + platename + File.separator;
if (!File.isDirectory(platefolder))
File.makeDirectory(platefolder);
print("Processing " + platename);
if (is("Batch Mode"))
setBatchMode(false); // has to be false for ROI Manager to open, and to display image to user
// user-directed creation of substack containing time points relevant to the germination assay
open(ppdir + platefile);
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("Time range selection");
Dialog.addMessage("Please note first and last slice to be included for germination analysis, and indicate it in the next step.");
Dialog.addCheckbox("First and last slices have been noted", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
roiManager("deselect");
run("Make Substack...");
substack = getTitle();
setSlice(nSlices);
if (ppdirno == 0) {
roiManager("reset");
run("ROI Manager...");
setTool("Rectangle");
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("Group Selection");
Dialog.addMessage("Select each group, and add to ROI manager. ROI names will be saved.\n" +
"Please use only letters (a/A), numbers (1) and/or dashes (-) in the ROI names.\n" + // to avoid file save issues
"ROIs cannot share names.");
Dialog.addCheckbox("All groups have been added to and labelled in ROI Manager", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
} else {
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("Group Selection");
Dialog.addMessage("Modify group selection and labels if needed.");
Dialog.addCheckbox("All groups have been added to and labelled in ROI Manager", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
}
roicount = roiManager("count");
run("Select None");
roicount = roiManager("count");
setBatchMode(true); //set back to true for faster cropping and saving
for (roino = 0; roino < roicount; roino ++) {
roiManager("select", roino);
roiname = Roi.getName;
groupdir = platefolder + File.separator + roiname + File.separator;
File.makeDirectory(groupdir);
roitype = Roi.getType;
if (roitype != "rectangle") {
run("Duplicate...", "duplicate");
run("Make Inverse");
run("Clear", "stack");
} else {
run("Duplicate...", "duplicate");
}
groupimg = getTitle();
saveAs("Tiff", groupdir + roiname + ".tif");
close();
// duplicate only the first slice and saves it, for faster masking/thresholding in getPositions so there is not too much waiting time for user between plates
setSlice(1);
run("Duplicate...", "use");
firstslice = getTitle();
selectWindow(substack);
setSlice(nSlices);
run("Duplicate...", "use");
lastslice = getTitle();
run("Images to Stack");
saveAs("Tiff", groupdir + "firstslice.tif");
close("firstslice.tif");
}
close(platefile);
close("Substack*");
}
}
}
function seedAnalysisGM() {
/* Image is thresholded to highlight seeds and remove noise as best as possible, then a binary mask is created.
* Seed positions are determined based on the first slice, using area and circularity to distinguish seed from trash.
* Based on these positions, the perimeter of the seeds through each slice is recorded.
* Perimeter was determined experimentally to be the most robust parameter for tracking germination.
* A graphical output is produced, highlighting the detected seeds in ROIs, to faciliate troubleshooting if needed.
*/
print("\nStep 2/2 Tracking germination...");
if (is("Batch Mode"))
setBatchMode(false); // for ROI manager to work
listIngermdir = getFileList(germdir);
for (platefolderno = 0; platefolderno < listIngermdir.length; platefolderno ++) { // main loop through plates
platefolder = listIngermdir[platefolderno];
if (indexOf(platefolder, "plate") >= 0) { // to avoid processing any random files in the folder
platedir = germdir + platefolder;
platename = File.getName(platedir);
print("Processing " + platename);
listInplatefolder = getFileList(platedir);
for (groupfolderno = 0; groupfolderno < listInplatefolder.length; groupfolderno ++) {
groupfolder = listInplatefolder[groupfolderno];
groupdir = platedir + groupfolder;
groupname = File.getName(groupdir);
listIngroupdir = getFileList(groupdir);
open(groupdir + "firstslice.tif");
// img = getTitle();
// setSlice(1);
// run("Duplicate...", "use");
tempmask = getTitle();
print("Analyzing " + groupname);
selectWindow(tempmask);
// masking and thresholding of seeds
run("Subtract Background...", "rolling=30 stack");
run("Convert to Mask", "method=Triangle background=Dark calculate");
run("Options...", "iterations=1 count=4 do=Dilate stack");
run("Remove Outliers...", "radius=2 threshold=50 which=Dark stack");
nS = nSlices;
for (sliceno = 1; sliceno <= nS; sliceno ++) {
setSlice(sliceno);
curslicelabel = getInfo("slice.label");
// day slices are processed more to make seed perimeters more comparable to night slices
// night slices have lower contrast so seeds appear smaller than they are after thresholding
if (indexOf(curslicelabel, "day") > 0) {
run("Remove Outliers...", "radius=3 threshold=50 which=Dark");
}
}
roiManager("reset");
setSlice(1);
run("Create Selection");
run("Colors...", "foreground=black background=black selection=red");
roiManager("Add");
roiManager("select", 0);
if (selectionType() == 9) {
roiManager("split");
roiManager("select", 0);
roiManager("delete");
}
// delete trash ROI which are features detected as below a certain area
// using table as a workaround to roi indexes changing if deletion happens one by one
roicount = roiManager("count");
roiarray = Array.getSequence(roicount);
run("Set Measurements...", "area center shape redirect=None decimal=5");
roiManager("select", roiarray);
roiManager("multi-measure");
tp = "Trash positions";
Table.create(tp);
nr = nResults;
if (platefolderno == 0 && groupfolderno == 0) {
lowerareathreshold = 0.002;
higherareathreshold = 0.02;
lowercircthreshold = 0.4;
if (DEBUG) {
Dialog.create("Seed detection parameters");
Dialog.addMessage("DEBUG: Detection parameters may be modified to accommodate for specific experiments");
Dialog.addNumber("Lower Area Threshold", 0.002);
Dialog.addNumber("Higher Area Threshold", 0.2);
Dialog.addNumber("Lower Circularity Threshold", 0.4);
Dialog.show();
lowerareathreshold = Dialog.getNumber();
higherareathreshold = Dialog.getNumber();
lowercircthreshold = Dialog.getNumber();
}
}
for (row = 0; row < nr; row ++) {
nrTp = Table.size(tp); // number of rows
area = getResult("Area", row);
if (area < lowerareathreshold) { // detected object is very small
Table.set("Trash ROI", nrTp, row, tp);
}
if (area > higherareathreshold) { // or very large
Table.set("Trash ROI", nrTp, row, tp);
}
circ = getResult("Circ.", row); // or does not fit normal seed shape
if (circ < lowercircthreshold) {
Table.set("Trash ROI", nrTp, row, tp); //set as trash to be deleted
}
}
if (Table.size(tp) > 0) {
trasharray = Table.getColumn("Trash ROI", tp);
roiManager("select", trasharray);
roiManager("delete");
}
close(tp);
close("Results");
roicount = roiManager("count");
// number remaining ROIs
for (roino = 0 ; roino < roicount; roino ++) {
roiManager("select", roino);
roiManager("rename", roino + 1); // first roi is 1
}
// prompt user to delete any non-detected trash, then re-number as above
Roi.setStrokeWidth(2);
Roi.setStrokeColor("red");
run("Labels...", "color=white font=18 show use draw");
roiManager("Show All with labels");
roiManager("Associate", "false");
roiManager("Centered", "false");
roiManager("UseNames", "true");
userconfirm = false;
while (!userconfirm) {
Dialog.createNonBlocking("User-guided seedling labelling");
Dialog.addMessage("Please delete any ROIs that should not be included into analysis, " +
"e.g. objects wrongly recognized as seeds." +
"\nUnrecognized seeds can also be added as ROIs.");
Dialog.addCheckbox("ROIs have been checked", false);
Dialog.show();
userconfirm = Dialog.getCheckbox();
}
roicount = roiManager("count");
for (roino = 0 ; roino < roicount; roino ++) {
roiManager("select", roino);
roiManager("rename", roino + 1); // first roi is 1
}
roiManager("save", groupdir + groupname + " seedpositions.zip");
close(tempmask);
}
}
}
for (platefolderno = 0; platefolderno < listIngermdir.length; platefolderno ++) { // main loop through plates
platefolder = listIngermdir[platefolderno];
if (indexOf(platefolder, "plate") >= 0) { // to avoid processing any random files in the folder
platedir = germdir + platefolder;
platename = File.getName(platedir);
//print("Processing " + platename);
listInplatefolder = getFileList(platedir);
for (groupfolderno = 0; groupfolderno < listInplatefolder.length; groupfolderno ++) {
groupfolder = listInplatefolder[groupfolderno];
groupdir = platedir + groupfolder;
groupname = File.getName(groupdir);
listIngroupdir = getFileList(groupdir);
open(groupdir + groupname + ".tif");
roiManager("reset");
open(groupdir + groupname + " seedpositions.zip");
img = getTitle();
run("Subtract Background...", "rolling=30 stack");
run("Convert to Mask", "method=Triangle background=Dark calculate");
run("Options...", "iterations=1 count=4 do=Dilate stack");
run("Remove Outliers...", "radius=2 threshold=50 which=Dark stack");
roicount = roiManager("count");
roiarray = Array.getSequence(roicount);
// Coordinates (center) of each detected object is organized, so that the seeds are numbered left to right, then top to bottom
// this is to facilitate troubleshooting if the user has to match seed positions and numbers to the data in the output table
run("Clear Results");
run("Set Measurements...", "center display redirect=None decimal=5");
roiManager("select", roiarray);
roiManager("multi-measure");
seedpositions = "Seed Positions";
Table.rename("Results", seedpositions);
xmseeds = newArray(roicount);
ymseeds = newArray(roicount);
for (seednumber = 0; seednumber < roicount; seednumber ++) {
xmcurrent = Table.get("XM", seednumber, seedpositions);
ymcurrent = Table.get("YM", seednumber, seedpositions);
xmseeds[seednumber] = xmcurrent;
ymseeds[seednumber] = ymcurrent;
}
ymascendingindexes = Array.rankPositions(ymseeds);
xmascendingindexes = Array.rankPositions(xmseeds);
sortedycoords = "sorted Y coordinates";
sortedxcoords = "sorted X coordinates";
Table.create(sortedycoords);
Table.create(sortedxcoords);
rowno = 0; // assume no row of seeds to start with
col = 0 ; // current col selection is 0
colname = "col" + col + 1;
Table.set(colname, rowno, ymseeds[ymascendingindexes[0]], sortedycoords);
Table.set(colname, rowno, xmseeds[ymascendingindexes[0]], sortedxcoords);
for (roino = 1; roino < roicount; roino++) {
ydiff = (ymseeds[ymascendingindexes[roino]]) - (ymseeds[ymascendingindexes[roino-1]]);