-
Notifications
You must be signed in to change notification settings - Fork 0
/
planar_2d_1.geo
95 lines (71 loc) · 2.77 KB
/
planar_2d_1.geo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
// ----------------------------------------------------------------------------
//
// Gmsh GEO file
//
// Homogenous domain for 2D planar problem
// - structured quadrilateral mesh
//
// ----------------------------------------------------------------------------
// Copyright (C) 2022 Adeeb Arif Kor
// ------------------------------------------------------------------------- //
// Geometry and mesh parameters
// ------------------------------------------------------------------------- //
speedOfSound = 1500;
sourceFrequency = 500000;
wavelength = speedOfSound / sourceFrequency;
domainRadius = 0.035;
domainLength = 0.12;
sourceRadius = 0.01;
numElementPerWavelength = 3;
hmin = 0.005; // placeholder for the mesh size
// ------------------------------------------------------------------------- //
// Rectangle 1 //
// ------------------------------------------------------------------------- //
Point(1) = {0., -sourceRadius, 0., hmin};
Point(2) = {domainLength, -sourceRadius, 0., hmin};
Point(3) = {domainLength, sourceRadius, 0., hmin};
Point(4) = {0., sourceRadius, 0., hmin};
Line(1) = {1, 2};
Line(2) = {2, 3};
Line(3) = {3, 4};
Line(4) = {4, 1};
Line Loop(101) = {1, 2, 3, 4};
Ruled Surface(102) = {101};
// ------------------------------------------------------------------------- //
// Rectangle 2 //
// ------------------------------------------------------------------------- //
Point(5) = {0., -domainRadius, 0., hmin};
Point(6) = {domainLength, -domainRadius, 0., hmin};
Line(5) = {1, 5};
Line(6) = {5, 6};
Line(7) = {6, 2};
Line Loop(201) = {5, 6, 7, -1};
Ruled Surface(202) = {201};
// ------------------------------------------------------------------------- //
// Rectangle 3 //
// ------------------------------------------------------------------------- //
Point(7) = {0., domainRadius, 0., hmin};
Point(8) = {domainLength, domainRadius, 0., hmin};
Line(8) = {4, 7};
Line(9) = {7, 8};
Line(10) = {8, 3};
Line Loop(301) = {8, 9, 10, 3};
Ruled Surface(302) = {301};
// ----------------------- //
// Tag curves and surfaces //
// ----------------------- //
Physical Curve(1) = {4};
Physical Curve(2) = {2, 6, 7, 9, 10};
Physical Curve(3) = {5, 8};
Physical Surface(1) = {102, 202, 302};
// =============== //
// Set transfinite //
// =============== //
Transfinite Line {1, 3, 6, 9} = numElementPerWavelength * domainLength
/ wavelength + 1;
Transfinite Line {2, 4} = numElementPerWavelength * 2 * sourceRadius
/ wavelength + 1;
Transfinite Line {5, 7, 8, 10} = numElementPerWavelength * (domainRadius
- sourceRadius) / wavelength + 1;
Transfinite Surface "*";
Recombine Surface "*";