forked from lanl/tardigrade-micromorphic-elasto-plasticity
-
Notifications
You must be signed in to change notification settings - Fork 0
/
CMakeLists.txt
151 lines (135 loc) · 6.75 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
#===================================================================================================== PROJECT SETUP ===
cmake_minimum_required(VERSION 3.14)
project(tardigrade_micromorphic_elasto_plasticity)
# Set common project paths relative to project root directory
set(CPP_SRC_PATH "src/cpp")
set(CPP_TEST_PATH "${CPP_SRC_PATH}/tests")
set(CMAKE_SRC_PATH "src/cmake")
set(DOXYGEN_SRC_PATH "docs/doxygen")
set(SPHINX_SRC_PATH "docs/sphinx")
# Add flag for whether to build the python bindings
set(TARDIGRADE_MICROMORPHIC_ELASTO_PLASTICITY_BUILD_PYTHON_BINDINGS ON CACHE BOOL "Flag for whether to build the python bindings")
# Add the cmake folder to locate project CMake module(s)
set(CMAKE_MODULE_PATH "${PROJECT_SOURCE_DIR}/${CMAKE_SRC_PATH}" ${CMAKE_MODULE_PATH})
# Set build type checks
string(TOLOWER "${CMAKE_BUILD_TYPE}" cmake_build_type_lower)
set(upstream_required "")
set(not_conda_test "true")
if(cmake_build_type_lower STREQUAL "release")
set(upstream_required "REQUIRED")
elseif(cmake_build_type_lower STREQUAL "conda-test")
set(upstream_required "REQUIRED")
set(not_conda_test "false")
endif()
# Get version number from Git
if(${not_conda_test} STREQUAL "true")
# TODO: On osx-arm64 some c++ projects struggle to find $PREFIX/bin/python during conda-builds and others don't.
# Trace the source and remove the hint when CMake configures with the correct python version during conda-build.
# FIXME: troubleshoot sstbigbird/RHEL8 python interpretter mismatch
# https://re-git.lanl.gov/aea/material-models/tardigrade_micromorphic_tools/-/issues/9
if (DEFINED ENV{PREFIX})
set(Python_ROOT_DIR "$ENV{PREFIX}/bin")
elseif (DEFINED ENV{CONDA_PREFIX})
set(Python_ROOT_DIR "$ENV{CONDA_PREFIX}/bin")
endif()
find_package(Python COMPONENTS Interpreter REQUIRED)
execute_process(COMMAND python -m setuptools_scm
OUTPUT_VARIABLE ${PROJECT_NAME}_VERSION_STRING_FULL
OUTPUT_STRIP_TRAILING_WHITESPACE)
if(${${PROJECT_NAME}_VERSION_STRING_FULL} STREQUAL "")
set(${PROJECT_NAME}_VERSION 0.0.0)
else()
string(REGEX MATCH "[0-9]+\.[0-9]+\.[0-9]+" ${PROJECT_NAME}_VERSION ${${PROJECT_NAME}_VERSION_STRING_FULL})
endif()
project(${PROJECT_NAME} VERSION ${${PROJECT_NAME}_VERSION})
endif()
# Add installation directory variables
include(GNUInstallDirs)
# Make the code position independent
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
# Set the c++ standard
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED True)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -pedantic")
if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -lrt")
endif()
# Enable CTest
enable_testing()
#================================================================================================= FIND DEPENDENCIES ===
# Find eigen
find_package(Eigen3 3.3 REQUIRED NO_MODULE)
include_directories(${EIGEN3_INCLUDE_DIR})
if(EIGEN3_FOUND)
message(STATUS "Found Eigen3: ${EIGEN3_INCLUDE_DIR}")
endif()
# Find related, but external, projects in installed environment
include(FetchContent)
set(upstream_packages "tardigrade_error_tools" "tardigrade_vector_tools" "tardigrade_constitutive_tools" "tardigrade_solver_tools" "tardigrade_micromorphic_tools" "tardigrade_hydra" "tardigrade_micromorphic_linear_elasticity")
if(${not_conda_test} STREQUAL "false")
# During conda-build testing, we must find the installed project files as if they were an external project
set(upstream_packages ${upstream_packages} ${PROJECT_NAME})
endif()
foreach(package ${upstream_packages})
string(TOUPPER "${package}" package_upper)
set(${package_upper}_BUILD_PYTHON_BINDINGS ${TARDIGRADE_MICROMORPHIC_ELASTO_PLASTICITY_BUILD_PYTHON_BINDINGS} CACHE INTERNAL "Setting ${package}'s python binding flag to the global value")
find_package(${package} ${upstream_required} CONFIG)
if(${package}_FOUND)
message(STATUS "Found ${package}: ${${package}_DIR}")
else()
# Find related, but external, projects using FetchContent and building locally
message(WARNING "Did not find an installed ${package} package. Attempting local build with FetchContent.")
if(NOT DEFINED ${package_upper}_FETCHCONTENT_VERSION)
set(${package_upper}_FETCHCONTENT_VERSION "origin/dev")
endif()
message("${package_upper} is being built with version ${${package_upper}_FETCHCONTENT_VERSION}")
# TODO: Decide how to handle main/dev build differences. bash env variables for GIT TAG?
FetchContent_Declare(
${package}
GIT_REPOSITORY http://github.com/UCBoulder/${package}.git
GIT_TAG ${${package_upper}_FETCHCONTENT_VERSION}
)
FetchContent_MakeAvailable(${package})
endif()
endforeach(package)
#=============================================================================================== ADD PROJECT TARGETS ===
# MUST COME AFTER DEPENDENCY LOCATING
# Add project source directories
if(${not_conda_test} STREQUAL "true")
include_directories(${CPP_SRC_PATH})
add_subdirectory(${CPP_SRC_PATH})
endif()
# Only add tests and documentation for current project builds. Protects downstream project builds.
if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
# Find Boost and add tests
find_package(Boost 1.53.0 REQUIRED COMPONENTS unit_test_framework)
add_subdirectory(${CPP_TEST_PATH})
# Add docs
if(${not_conda_test} STREQUAL "true")
add_subdirectory(${DOXYGEN_SRC_PATH})
add_subdirectory(${SPHINX_SRC_PATH})
endif()
endif()
#==================================================================================== SETUP INSTALLATION CMAKE FILES ===
if(${not_conda_test} STREQUAL "true")
foreach(package ${PROJECT_NAME} ${UMAT})
include(CMakePackageConfigHelpers)
write_basic_package_version_file("${package}ConfigVersion.cmake"
VERSION ${PROJECT_VERSION}
COMPATIBILITY SameMajorVersion)
configure_package_config_file(
"${PROJECT_SOURCE_DIR}/${CMAKE_SRC_PATH}/Config.cmake.in"
"${PROJECT_BINARY_DIR}/${package}Config.cmake"
INSTALL_DESTINATION
${CMAKE_INSTALL_DATAROOTDIR}/${package}/cmake)
# CMake won't build the targets for local builds of upstream projects
if(cmake_build_type_lower STREQUAL release)
install(EXPORT ${package}_Targets
FILE ${package}Targets.cmake
DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${package}/cmake)
endif()
install(FILES "${PROJECT_BINARY_DIR}/${package}Config.cmake"
"${PROJECT_BINARY_DIR}/${package}ConfigVersion.cmake"
DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${package}/cmake)
endforeach(package)
endif()